Друид
Кошка / стэлс
По первому нажатию, в какой бы форме вы не находились, вы превращаетесь в кошку, когда вы в кошке, и вы не в стелсе, то юзается стелс, а если вы в стелсе, то он снимается, вообщем стремился к тому как у роги, нажал стелс, нажал вышел из стелса
Код:
/cast [stance:1] [stance:2] [stance:4][stance:5] [nostance] Облик кошки(Смена облика)
/cast [stance:3] [nostealth] Крадущийся зверь
/cancelaura [stealth] Крадущийся зверь
Смена форм
Не в бою не в кошке, жмем раз и мы в кошке
Не в бою и уже в кошке- в стелс (невидимость)
В бою в любой форме - раз нажал - ты в гепарде - еще раз нажал - ты в кошке - раз нажал - ты снова в гепарде и всё по новой... очень удобно убегать
В любое время в любом месте при любых условиях - клик + шифт - стать медведем
Код:
/cast [modifier:alt] Облик медведя(Смена облика)
/stopmacro [modifier:alt]
/cast [stance:1/2/4][nostance] Облик кошки(Смена облика)
/cast [stance:3][nostealth, nocombat] Крадущийся зверь
/stopmacro [nocombat]
/cast Походный облик(Смена облика)
Лечение без потери цели
Этот макрос хилит ВАС не зависимо кто в цели, без потери цели, если нужно , например на арене, впишите имя нужного вам человека - и будет хилить его, без потери текущей цели
Код:
/target Имя вашего персонажа
/cast Природная Стремительность
/cast Целительное Прикосновение
/TargetLastTarget
Озарение без потери цели
Кидает Озарение на того, чьё имя вписано, без потери текущей цели.
Код:
#show Озарение
/target Имя персонажа
/cast Озарение
/TargetLastTarget
Озарение
Нажал макрос - Озарение себя, нажал с шифтом - озарение цели.
Код:
/cast [nomodifier,target:player] Озарение
/cast [modifier:shift,target:target] Озарение
Форма путешествия
Биндится на одну клавишу и все формы для путешествия.
В воде - тюлень, в бою, и там где нельзя летать (не аутденды) - Гепард. Вне боя, и в Аутлендах - Птица.
P.S. Если у вас эпик формы, то пишите обычное название и все
P.S. [stance:5] пишется в том случае, если у вас есть Мункин форма, или форма дерева, если нету, лучше не писать, а то будет выдавать ошибку.
Код:
/cancelform [stance:1/3][stance:5] [stance:4, flyable, nocombat]
/cast [nostance, swimming] Водный облик(Смена облика); [nostance, flyable, nocombat] Быстрый воздушный облик(Смена облика); [nostance, outdoors]Походный облик(Смена облика)
Охотник
Ближняя атака
Код:
/циклзаклинаний Подрезать крылья, Удар ящера, Подрезать крылья
/castrandom [target=target, exists] Укус мангуст
Метка + атака
Очень полезный макрос. Устанавливает метку охотника на ващу цель и дает команду вашему питомцу атаковать цель.
Код:
/закл Метка Охотника
/питомецатака
Перенаправление
Самый простой макрос на перенаправление, цель не меняет.
Код:
/target Pet
/cast Перенаправление
/target LastTarget
Цикл БМ охотника
Код:
#showtooltip Верный выстрел
/cast !Автоматическая стрельба
/cast [target=pettarget, exists] Команда \"Взять!\"
/cast Верный выстрел
/script UIErrorsFrame:Clear()
Паладин
Сбить Тотем заземления
Этот макрос сбивает замедляющий тотем, если такой имеется, если нет то кастит стан на цель.
Код:
#showtooltip Молот правосудия
/focus
/cleartarget
/target Тотем заземления
/cast [target=target,exists,harm] Длань возмездия; [target=focus] Молот правосудия
/target focus
/clearfocus
Танкование: Снятие дебаффов в бою
нятие дебаффов в бою при танковании (стакующиеся доты, фир и т.д. ) Снимает с себя бедаффы использую божественный щит и мгновенно снимает бафф щита, что бы избежать потери аггро.
Код:
#showtooltip Божественный щит
/cancelaura Божественный щит
/cast Божественный щит
Танкование: Снятие эффектов, понижающих аггро
Снимает все возможные понижающие аггро эффекты, при танковании.
Код:
#showtooltip Щит небес
/cast Щит небес
/cancelaura Длань спасения
/cancelaura Длань защиты
/cancelaura Божественный щит
Удар воина света + двуручка
1) Одевает двуручное оружие
2) Если Удар Воина Света на кд, то начинает бить авто атакой.
3) Кастует Удар Воина Света
Код:
#showtooltip Удар воина света
/equip (название оружия)
/startattack
/cast Удар воина света
Жрец
Макрос на воскрешение
При выделении цели жать кнопку (на которой макрос) или левую кнопку мыши на труп товарища, Вы начинаете его ресать и говорите кого ресаете.
Нажимая правую кнопку мыши применяется спел как обычно (таким образом можна реснуть "испустившего дух")
Код:
#showtooltip Воскрешение
/cast [button:2]Воскрешение;[help,dead]Воскрешение
/stopmacro [button:2]
/stopmacro [nohelp]
/к Воскрешаю %t\'а
Шакл и последующий решакл без выделения таргета
Код:
#showtooltip Сковывание нежити
/clearfocus [modifier:alt][target=focus,dead][target=focus,help][target=focus,noexists]
/focus [target=focus,noexists]
/cast [target=focus] Сковывание нежити
Разбойник
Полезный макрос для тех, кто в билде "Шадоустеп":
Код:
/use (название триньки)
/use Shadowstep
/use Vanish(Rank 3)
/cast Cheap Shot
Отличный макрос для вылавливания роги из инвиза(стелса), макрос автаматически садит сап на цель. Макрос сам ищет цель и садит сап на неё:
Код:
#showtooltip Ошеломление
/console targetNearestDistance 8,000000
/targetenemy [noharm][dead]
/cast [harm, nodead] Ошеломление
/cleartarget
Хладнокровие и потрошение сразу:
Код:
/cast Хладнокровие
/use Потрошение(Уровень 12)
Отличный макрос для уклонения, если у вас есть талант "Призрачный удар":
Код:
/cast Ускользание(Уровень 2)
/use Призрачный удар
Полезный макрос, когда нужно убежать от кого-либо:
Этот макрос рабочий только у того, у кого есть профессия инженерия.
!!!Там где Сапоги триумфа гневного гладиатора, меняете на свои сапоги с заточкой на нитроускорители. По желанию можно добавить плащ Теней.
Код:
/use Сапоги триумфа гневного гладиатора
/cast Исчезновение(Уровень 3)
Макрос если Вас выловили из стелса:
Если на вас напал рог и вы не успели его выловить из стелса, этот макрос юзнёт тринку от стана, затем ваниш и подлый трюк. Цель выбирать не надо в макросе указанно вот это всё на ближайшую цель.
Вместо исчезновения , Вы можете поставить блинд.
Код:
/console targetNearestDistance 8,000000
/targetenemy [noharm][dead]
/use Медальон Орды
/cast Исчезновение(Уровень 3)
/use Подлый трюк
Хладнокровие + смертельный бросок:
Код:
/cast Хладнокровие
/cast Смертельный бросок(Уровень 3)
Хладнокровие + потрошение + исчезновение + амбуш (удар в спину, или как-то так):
Код:
/cast Хладнокровие
/cast Потрошение(Уровень 12)
/use Исчезновение(Уровень 3)
/cast Внезапный удар(Уровень 10)
Шаман
Тотемы на случай защиты
Код:
/castsequence reset=combat/20 Тотем исцеляющего потока, Тотем каменной кожи, Тотем защиты от сил природы, Тотем защиты от магии
Тотемы на случай атаки
Код:
/castsequence reset=combat/20 Тотем силы земли, Тотем защиты от магии льда, Тотем защиты от огня, Тотем неистовства ветра
Тотемы на случай "отрыва" от врага
Код:
/castsequence reset=combat/20 Тотем оков земли, Тотем магмы
Снятие ядов и болезней
1 - просто жмём - снятие яда;
2 - жмём с шифтом - излечиваем болезнь;
3 - если выбран враг или никто не выбран, то первые 2 пункта применяются к себе.
Код:
/cast [help,nomodifier] Выведение яда;
/cast [help,modifier:shift] Излечение болезни;
/cast [target=player,nomodifier] Выведение яда
/cast [target=player,modifier:shift] Излечение болезни
Щиты на одной кнопке
На одной кнопке основные щиты для рестор шамана.
Работает следующим образом:
1 - Просто жмём на кнопку - водный щит на себя;
2 - Жмём на кнопку с шифтом + выбрали себя или врага - земляной щит на себя;
3 - Жмём на кнопку с шифтом + выбран дружественный игрок, земляной щит на него.
Код:
/cast [modifier: shift, help] Щит Земли(Уровень 3); [modifier: shift, target=player] Щит Земли(Уровень 3); [target=player] Водный щит
Чернокнижник
Жизнеотвод + Похищение жизни
Щелкнуть два раза. Восстанавливает ману из жизни, а потом сосет жизнь из противника
Код:
/castsequence reset=target/combat жизнеотвод, похищение жизни
Запрет чар охотника скверны
Макрос для охотника скверны. Охотник скверны кастует "Запрет чар" на выбранную цель или на цель, на которую наведен курсор мыши
Код:
/cast [target=focus,exists,harm,nodead,pet:Охотник скверны][target=mouseover,harm,exists,nodead,pet:Охотник скверны] Запрет чар; Запрет
Огненный щит на всех
Для пати. Щелкнуть пять раз (по кол-ву членов пати). При комманде "бафаемся" Имп быстро вешает щит на всех.
Код:
/targetparty
/cast огненный щит
Призыв коня погибели
В зависимости от того где вы находитесь, макрос вызывает нужного маунта. Если вы в аутленде, то вызывается флай маунт, если в азероте или на БГ - вызывает локовского коня.
Код:
#showtooltip Призыв коня погибели
/стопмакро [flying]
/закл [outdoors,nomounted,nomodifier:ctrl,flyable] Ваш флай маунт; [outdoors,nomounted] Призыв коня погибели(Призыв)
/спешиться [mounted]
Страх
Первым нажатием макрос фокусит противника и фиряет его, а последующие нажатия фиряют эту зафокусированную цель внезависимости от того какая цель у вас выделена сейчас (цель не слетает). При нажатии макроса с зажатым ctrl вы очищаете фокус. Вообщем макрос для того, чтобы можно было одного бить и в это же время другого постоянно фирять не переключая цель.
Код:
/focus [target=focus, noexists][target=focus, dead] mouseover
/cast [nomodifier, target=focus] Страх(уровень 3)
/stopmacro [nomodifier]
/clearfocus [modifier:ctrl]
Рыцарь смерти
Сайленс
Есть у Вас блад руна, или нет, не имеет значения, Вы скастуете Удушение в любом случае. Полезно, когда нужен сайленс, а блад руна на кд. Кровоотвод не будет использован, если Вы не в бою. Макрос возможно придется нажать 2 раза чтобы он сработал.
Код:
#showtooltip Удушение
/cast [combat] Кровоотвод
/cast Удушение
[/CODE]
Для анхоли ДК(3ветка)
Этим макросом гуля станет атаковать цель, при возможности чарджнется в неё и застанит.
Код:
#showtooltip Отгрызть
/petattack
/cast Прыжок
/cast Отгрызть
При зажатом шифте отхилит пета Ликом Смерти, без шифта просто скастует Лик Смерти. Если вы бегаете с личборном, то с зажатым ctrl Лик Смерти скастуется в себя.
Код:
#showtooltip
/cast [nomod] Лик Смерти; [mod:shift,target=pet] Лик Смерти, [mod:ctrl,target=self] Лик Смерти
Универсальный спам макрос на Удар плети. Собсно бьет ударом плети, по парри - бьет руник страйком + врубает режим автоатаки и дает пету команду атаковать выделенный таргет.
Код:
showtooltip
/cast Удар Плети(Уровень 4)
/cast Рунический удар
/startattack
/petattack
Самохил
Спам макрос на селф хил. Кастует Перерождение и хилит себя Ликом смерти.
Код:
/cast Перерождение
/cast [target=player] Лик смерти
Маг
Blink + разворот камеры
Прерывает любой каст или чанелинг и блинкует вас вперед, разворачивая камеру обзора на 180 градусов.
Код:
/stopcasting
/cast Скачок
/stopmacro [noharm]
/run FlipCameraYaw(180)
Атака элементаля
Для фрост мага и его элементаля (очень полезно в пвп против рогов)
Элементаль кастует зведу и атакует цель, выбранную вами.
Код:
/cast [pet] Холод
/питомецатака
Элементаль
Макрос на вызов элементаря по первому клику, по второму каст новы, по третьему атака!
Код:
#showtooltip Призыв элементаля воды
/cast [nopet] Призыв элементаля воды
/stopcasting
/cast Холод
/petattack
Быстрый Контр Спелл
Данный макрос нужен для быстрого реагирования на начало каста противника. Срывает Ваш каст в случае нажатия!
Код:
#showtooltip Антимагия
/stopcasting
/cast антимагия
Обьединение трех бафов
Обьединение трех бафов. ЛКМ - каст Ледяного доспеха, ПКМ - каст Магического доспеха, Клик на колесико - каст Раскаленного доспеха.
#showtooltip Ледяной доспех
Код:
/cast [button:2] Магический доспех; [button:3] Раскаленный доспех; Ледяной доспех;
Замедленное падение + невидимость
Обединение замедленного падения и невидимости в одну кнопку
Код:
#showtooltip Невидимость
/cast [button:2] Замедленное падение; Невидимость;
Щиты для фрост мага
ЛКМ - Ледяная преграда(Уровень 6)
ПКМ - Щит маны(Уровень 7)
Код:
#showtooltip Ледяная преграда(Уровень 6);
/cast [button:2] Щит маны(Уровень 7); [button:3]; Ледяная преграда(Уровень 6)
Баффы для фрост мага
ЛКМ - Чародейский интеллект(Уровень 6)
СКМ - Ослабление магии(Уровень 6)
ПКМ - Морозный доспех(Уровень 3)
Код:
#showtooltip Чародейский интеллект(Уровень 6)
/cast [button:2] Морозный доспех(Уровень 3); [button:3] Ослабление магии(Уровень 6); Чародейский интеллект(Уровень 6);
Воин
Макрос против кастеров
Для фурри варов, т.к у них в руках 2 двуручки:
Код:
/equip Ваш щит
/cast Оборонительная стойка
Переодеть обратно двуручку в левую руку (для фурри варов)
Код:
cast Стойка берсерка
/equip Ваше оружие, оружие в правой руке
/equipslot 17 Ваше оружие в левой руке
Для армс варов, т.к у них одноручка в правой руке, а в левой щит.
Код:
/equip Ваша одноручка
/equip Ваш щит
/use Оборонительная стойка
Переодеть обратно двуручку вместо щита и одноручки(армс вары)
Код:
/cast Стойка берсерка
/equipslot 16 Ваша двуручка
Бешеный рывок
Воин нападает на цель, при этом летит героический бросок
Код:
/cast Боевая стойка
/cast Рывок(Уровень 3)
/use Героический бросок